# http://www.ex-parrot.com/~tom/calcs/calcs/encyc/progs/src/bombrun.ctf
# ========================================================================
# Program name: Bomb Run
# 
#      Version: 1.0
#       Author: Tom Lynn
#         Date: 1997
#       Models: 9750, 9850, 9950
#
#
# Description:
#
# Your plane starts at the top of the screen above a large city
# and descends slowly.  It has to destroy all of the buildings
# before it hits them.
#
# * How To Play *
#
# Run the program "~BOMBRUN".
# 
# Press [EXE] when your plane is in the column just before the
# one you want the bomb dropped into.  That's all there is to it.


@@ Program "~BOMBRUN"
# Main routine

ViewWindow 1,127,0,1,63,0
For 1->A To 31
2+Int 12Ran#->C
For 1->B To C
Text 62-4C+4B,4A,"\."
Next
Next
1->A~B
(-)1->C
0->J~K
Lbl 0
Text 4B,4A," "
Isz A
If A>31
Then 1->A
Isz B
B>=15=>Goto 1
IfEnd
PxlTest 4B+2,4A+1
If Ans
Then "OOH(-)THAT HAD TO HURT!"
Stop
IfEnd
Text 4B,4A,">"
GetKey
Ans=>Ans->K
If C<0 And K=31
Then 4A->D
B->C
0->K
IfEnd
Prog "BRDROP"
J<>31=>Goto 0
Lbl 1
"WOW! I'M IMPRESSED!"


@@ Program "BRDROP"
# Bomb dropping routine

C>=0=>Text 4C+1,D," "
Text 4B,4A,">"
GetKey
Ans->K
If C=15 Or C<0
Then (-)1->C
0->K
For 1->X To 20
GetKey
Ans=>Ans->K
Next
Return
IfEnd
Isz C
PxlTest 4C+3,D
If Ans
Then For 4C+2->C To 56 Step 6
Text C,D," "
Next
Text 56,D," "
(-)1->C
Isz J
Else Text 4C,D,"."
IfEnd


# ========================================================================
# CTF compliant.  See http://www.york.ac.uk/~tw104/casio/ for details.
#
# More programs and information at:
#              http://www.ex-parrot.com/~tom/calcs/calcs/encyc/
#
# This file last compiled: Friday, 30 April, 1999
# ========================================================================